custom_trend.#execution_crashes.snapshots during past 90d
| where nb_crashes > 0
| summarize number_of_crashes_ = nb_crashes.sum() by context.device_platform
| sort number_of_crashes_ desc
デバイスハードウェア製造元ごとのクラッシュ総数とクラッシュを持つデバイスの数を観察します。
custom_trend.#execution_crashes.snapshots during past 90d
| where hardware_manufacturer != "VMWare"
| where hardware_manufacturer != null
| summarize number_of_crashes_ = nb_crashes.sum(), number_of_devices_ = device.count() by hardware_manufacturer
| sort number_of_crashes_ desc
Windows 11 への移行のモニタリング
時間経過に伴う Windows 11 を搭載したデバイスの割合を追跡します。
カスタムトレンド定義
devices
| where operating_system.platform == windows
| list operating_system.name, hardware.type
カスタムトレンドデータの取得
custom_trend.#windows_migration.snapshots during past 300d
| where hardware_type !in [virtual, null]
| summarize ratio_with_windows_11 = countif(operating_system_name == "*windows 11*")/count() by 1d
起動時間のモニタリング
各デバイスの平均起動時間を追跡し、スリム化した構成を実装する効果をモニタリングします。
カスタムトレンド定義
devices during past 1d
| include device_performance.boots during past 1d
| compute boot_duration = duration.avg()
| list boot_duration, hardware.type
カスタムトレンドデータの取得
custom_trend.#boot_duration.snapshots during past 90d
| where (context.device_platform == "Windows" and hardware_type == laptop)
| summarize boot_duration_avg = boot_duration.avg() by 1d
起動時にアプリケーションクラッシュを伴うデバイスのモニタリング
アプリケーションの起動時に少なくとも1度のクラッシュを経験したデバイスの1日の台数を追跡します。
カスタムトレンド定義
devices during past 1d
| include execution.crashes during past 1d
| where crash_on_start == true
| compute crash_on_start_count = count()
| list crash_on_start_count
カスタムトレンドデータの取得
custom_trend.#crashes_on_start.snapshots during past 300d
| where crash_on_start_count > 0
| summarize devices_with_app_crashes_at_start = count() by 1d
異なるバイナリバージョンのCPU使用率をモニタリング
アプリケーションのバージョンごとの平均CPU使用率を追跡します。
カスタムトレンド定義
devices
| include execution.events during past 1d
| where binary.name == "zoom.exe"
| compute CPU_usage_ratio = ((cpu_time.sum()) * (100)) / ((execution_duration.sum()) * (number_of_logical_processors.max())), last_version = binary.version.last()
| list CPU_usage_ratio, last_version
カスタムトレンドデータの取得
custom_trend.#zoom_cpu_usage_ratio.snapshots during past 300d
| summarize c1 = CPU_usage_ratio.avg() by 1d, last_version
