Microsoft AVD

Microsoft Azure Virtual Desktop（AVD）はクラウド上で稼働し、仮想マシン（VM）は組織のAzureサブスクリプション内でホストされます。これにより、組織は仮想デスクトップの制御を集中化しながら、Azureが提供するスケーラブルなインフラストラクチャを活用できます。これは、オンプレミスのデータセンター依存を減らしながら、個人および共有の仮想デスクトップとアプリケーションの柔軟な提供を維持したい企業によく利用されます。

コネクタを設定する

セッションメタデータの取り込みのために、NexthinkをMicrosoft AVD APIに接続するように構成します。このステップにより、VDI エクスペリエンスモジュール内で洞察を拡張するためのコンテキストデータが利用可能になります。

コネクタをセットアップするには、Microsoft Azure Virtual Desktop 用コネクタに記載された手順を実行します。

VM上でCollectorをインストール

手動または自動デプロイメント

共有VDI: クラウドプラットフォームに展開されたマルチセッションホストにCollectorをインストールします。セッションホストがドメインに参加しており、適切なサイズでプロビジョニングされていることを確認してください。
パーソナルVDI（永続型）: 永続型デスクトップのプロビジョニングまたはオンボーディング時に標準エージェントとしてCollectorをインストールします。

両方のシナリオについて、以下のドキュメントに記載された手順を実行してください：

ゴールデンイメージベースのデプロイメント

プール型VDI（非永続性）はデプロイメントにゴールデンイメージを使用します。

以下のドキュメントに記載された手順を実行してください：

コネクタとCollectorをテストする

コネクタ

デバイスおよびセッションデータがコネクタ統合からの情報で補強されていることを、次のフィールドを確認することで確認します。

ディスクイメージ
デスクトッププール
仮想化タイプ

エンリッチメントをテストするために、VMにCollectorがインストールされており、その運用が確認されていることを次のクエリを実行して確認します。

devices
| where virtualization.desktop_broker == azure_virtual_desktop
| list name, hardware.type, virtualization.disk_image, virtualization.desktop_pool, virtualization.environment_name, virtualization.type, virtualization.last_update
| sort virtualization.last_update desc

クエリの実行についての詳細は、調査のドキュメントを参照してください。

VM上のCollector

必要に応じて、NexthinkサポートまたはNexthinkの担当者に連絡してください。

共有VDI

次のようなデータがNexthinkで表示されることを確認します。

デバイス ID
ユーザー名
デスクトッププール

これを確認するには、次のクエリを実行します：

vdi_sessions
| where device.virtualization.desktop_broker == azure_virtual_desktop and vdi_session.virtualization_type == shared
| list vdi_session.name, user.name, device.name, desktop_pool, first_seen
| sort first_seen desc

Pooled VDI

デプロイ後にインスタンスが以下を報告していることを確認してください：

ユニークデバイスID
正確なプール名
新しいブート時間

これを確認するには、次のクエリを実行します：

devices
| where virtualization.desktop_broker == azure_virtual_desktop and virtualization.type == pooled
| list device.name, virtualization.desktop_pool, boot.last_full_boot_time
| sort boot.last_full_boot_time desc

個人用VDI

次を一貫して報告することを確認してください：

デバイスIDと割り当てられたユーザー
再起動とログオンを通じたシステム稼働時間

これを確認するには、次のクエリを実行します：

devices
| where virtualization.desktop_broker == azure_virtual_desktop and virtualization.type == personal
| with session.vdi_events during past 168h
| compute number_of_sessions = vdi_session.count(), time_since_session_last_seen = end_time.last().time_elapsed(), last_user = user.name.last()
| include device_performance.boots during past 168h
| compute number_of_restarts = number_of_boots.sum()
| include session.logins during past 168h
| compute time_since_last_login = time.last().time_elapsed(), number_of_logons = number_of_logins.sum()
| list name, last_user, number_of_sessions, time_since_session_last_seen, number_of_logons, time_since_last_login, number_of_restarts, boot.last_full_boot_time.time_elapsed(), last_seen.time_elapsed()
| sort time_since_session_last_seen desc

クライアントデバイスにエンドポイントエージェントをインストール

企業管理デバイスにCollectorをインストール

組織によって中央管理されているクライアントデバイスに、選択したソフトウェアデプロイメントツールを使用して、適用されるすべてのデバイスにCollectorを配布します。

Collectorをインストールするドキュメントに記載されたプロシージャを実行してください。

VDIクライアント拡張はCollectorに組み込まれているため、別途インストールする必要はありません。

個人または自己管理のデバイスにVDI拡張機能をインストール

個人または自己管理デバイスに対して、VDIクライアント拡張をインストール可能にします。この軽量エージェントは、完全なCollectorをデプロイすることなく、限定的ながらも貴重なクライアントサイドのメトリックを提供します。

以下のドキュメントに記載されたプロシージャを実行してください：Nexthink VDIクライアント拡張機能のインストール。

クライアントデバイスをテスト

企業管理デバイス

管理されたクライアントデバイスから起動されたセッションでは、次のフィールドが表示されることを確認してください：

ラウンドトリップ時間
クライアントCPU使用率
Wi-Fi 信号強度
リンク速度

ネットワーク RTT は VM のみで Collector がインストールされている場合でも利用可能ですが、完全なクライアント性能情報にはエンドポイントに Collector をインストールする必要があります。インストールを確認するためには、クライアントのメトリックがセッションごとに報告されていることを確認してください。

クライアントデバイスが Collector を実行しており、Nexthink インスタンスにデータを報告している場合、その名前はデバイスビューへのリンクとして表示され、詳細情報やアクティビティを確認できます。

これを確認するには、次のクエリを実行します：

vdi_sessions
| with session.vdi_events during past 168h
| compute average_network_rtt = network_rtt.avg(), average_wifi_signal_strength = client.network.wifi_signal_strength.avg(), average_link_speed = client.network.wired_link_speed.avg(), average_client_cpu_usage = client.cpu.normalized_usage.avg(), last_client_plugin_version = client.plugin_version.last()
| list vdi_session.name, device.name, user.name, name, last_client.device.name, last_client_plugin_version, average_network_rtt, average_wifi_signal_strength, average_link_speed, average_client_cpu_usage
| sort last_seen desc

パートナー管理またはBYOデバイス

外部管理クライアントデバイスから起動されたセッションでは、次のフィールドが表示されることを確認してください：

ラウンドトリップ時間
クライアントCPU使用率
Wi-Fi 信号強度
リンク速度

ネットワーク RTT は VM のみで Collector がインストールされている場合でも利用可能ですが、完全なネットワーク性能情報にはクライアントデバイスに Collector または VDI クライアント拡張をインストールする必要があります。インストールを確認するためには、セッションのネットワーキングメトリックが報告されていることを確認してください。

VDI クライアント拡張がインストールされている場合、追加のデバイスデータはキャプチャされないため、クライアントデバイスのデバイスビューは利用できません。この場合、クライアント関連のパフォーマンス情報はVDIセッション内でのみ報告されます。

これを確認するには、次のクエリを実行します：

vdi_sessions
| with session.vdi_events during past 168h
| compute average_network_rtt = network_rtt.avg(), average_wifi_signal_strength = client.network.wifi_signal_strength.avg(), average_link_speed = client.network.wired_link_speed.avg(), average_client_cpu_usage = client.cpu.normalized_usage.avg(), last_client_plugin_version = client.plugin_version.last()
| list vdi_session.name, device.name, user.name, name, last_client.device.name, last_client_plugin_version, average_network_rtt, average_wifi_signal_strength, average_link_speed, average_client_cpu_usage
| sort last_seen desc

Last updated 13 days ago

Was this helpful?